home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib06.dsk
/
CIRCLES FROM LINES.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
1KB
|
37 lines
1 REM ******************************
2 REM * CIRCLES FROM LINES *
3 REM * BY T.L. GABRIELE *
4 REM * COPYRIGHT (C) 1981 *
5 REM * BY MICRO-SPARC INC *
6 REM * LINCOLN, MA 01773 *
7 REM ******************************
10 REM CIRCLES FROM LINES
20 REM ALL POSSIBLE LINE
30 REM SEGMENTS BETWEEN
40 REM NODE PAIRS
50 REM
60 DIM XP(25),YP(25)
70 TEXT : HOME : VTAB 3
80 INVERSE : PRINT : PRINT "CIRCLES FROM LINES": PRINT : NORMAL : PRINT
90 PRINT "HOW MANY NODES WOULD YOU LIKE?"
100 INPUT "(3 TO 25) (0 WILL EXIT)";N%
110 IF N% = 0 THEN END
120 IF N% <3 OR N% >25 THEN 90
130 VTAB 10
140 NL% = N% *(N% -1)/2
150 PRINT "WHEN YOU PRESS THE NEXT KEY I'LL DRAW": PRINT NL%;" LINES."
160 GET Z$
170 HGR2 : HCOLOR= 3
180 PI = 3.141592654
190 FOR I = 1 TO N%
200 TH = 2 *PI *I/N%
210 XP(I) = 139 *(1 + SIN(TH))
220 YP(I) = 91 *(1 - COS(TH))
230 NEXT I
240 FOR I = 1 TO N% -1
250 FOR J = I +1 TO N%
260 HPLOT XP(I),YP(I) TO XP(J),YP(J)
270 NEXT J
280 NEXT I
290 GET Z$
300 GOTO 70